1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
|
%{
/*
* rcfile_l.l -- lexer for the run control file
*
* For license terms, see the file COPYING in this directory.
*/
#include <string.h>
#include "config.h"
#include "fetchmail.h"
#include "rcfile_y.h"
int prc_lineno = 1;
%}
/* this doesn't work with Linux lex, see the INSTALL file */
%o 7000
%a 4000
%p 3000
%s NAME PREAUTH
%%
\"[^\"]*\" {
char buf[MSGBUFSIZE];
yytext[strlen(yytext)-1] = '\0';
escapes(yytext+1, buf);
yylval.sval = (char *) xstrdup(buf);
BEGIN(0);
return STRING;
}
\'[^\']*\' {
char buf[MSGBUFSIZE];
yytext[strlen(yytext)-1] = '\0';
escapes(yytext+1, buf);
yylval.sval = (char *) xstrdup(buf);
BEGIN(0);
return STRING;
}
"*" { BEGIN(0); return WILDCARD; }
<NAME>[^=;:, \t\r\n]+ {
char buf[MSGBUFSIZE];
escapes(yytext, buf);
yylval.sval = (char *) xstrdup(buf);
BEGIN(0);
return STRING;
}
set { return SET; }
logfile { return LOGFILE; }
idfile { return IDFILE; }
daemon { return DAEMON; }
syslog { return SYSLOG; }
invisible { return INVISIBLE; }
postmaster { return POSTMASTER; }
bouncemail { return BOUNCEMAIL; }
warnings { return WARNINGS; }
defaults { return DEFAULTS; }
server { return POLL; }
poll { return POLL; }
skip { return SKIP; }
via { return VIA; }
aka { return AKA; }
local(domains) { return LOCALDOMAINS; }
proto(col)? { return PROTOCOL; }
service { return SERVICE; }
port { return PORT; }
interval { return INTERVAL; }
preauth(enticate)? { BEGIN(PREAUTH); return PREAUTHENTICATE; }
kerberos(_v)?4 { BEGIN(0); return KERBEROS4; }
kerberos(_v)?5 { BEGIN(0); return KERBEROS5; }
kerberos { BEGIN(0); return KERBEROS; }
<PREAUTH>password { BEGIN(0); return PASSWORD; }
timeout { return TIMEOUT;}
envelope { return ENVELOPE; }
qvirtual { return QVIRTUAL; }
user(name)? {BEGIN(NAME); return USERNAME; }
pass(word)? {BEGIN(NAME); return PASSWORD; }
folder(s)? { return FOLDER; }
smtp(host)? { return SMTPHOST; }
smtpaddress { return SMTPADDRESS; }
antispam { return SPAMRESPONSE; }
mda { return MDA; }
bsmtp { return BSMTP; }
lmtp { return LMTP; }
pre(connect)? { return PRECONNECT; }
post(connect)? { return POSTCONNECT; }
netsec { return NETSEC; }
interface { return INTERFACE; }
monitor { return MONITOR; }
plugin { return PLUGIN; }
plugout { return PLUGIN; }
batchlimit { return BATCHLIMIT; }
fetchlimit { return FETCHLIMIT; }
expunge { return EXPUNGE; }
properties { return PROPERTIES; }
is { BEGIN(NAME); return IS; }
here { return HERE; }
there { return THERE; }
to { BEGIN(NAME); return TO; }
= { BEGIN(NAME); return MAP; }
nobouncemail |
nouidl |
nocheckalias |
nodns |
noenvelope |
nokeep |
noflush |
nofetchall |
norewrite |
noforcecr |
nostripcr |
nopass8(bits)? |
nodropstatus |
nomimedec(ode)? {
yyless(2);
return NO;
}
no {return NO;}
keep { return KEEP; }
flush { return FLUSH; }
fetchall { return FETCHALL; }
rewrite { return REWRITE; }
forcecr { return FORCECR; }
stripcr { return STRIPCR; }
pass8(bits)? { return PASS8BITS; }
dropstatus { return DROPSTATUS; }
mimedec(ode)? { return MIMEDECODE; }
dns { return DNS; }
uidl { return UIDL; }
checkalias { return CHECKALIAS; }
limit { return LIMIT; }
with {/* EMPTY */}
and {/* EMPTY */}
has {/* EMPTY */}
wants {/* EMPTY */}
options {/* EMPTY */}
[;:,] {/* EMPTY */}
(auto)|(AUTO) { yylval.proto = P_AUTO; return PROTO; }
(pop2)|(POP2) { yylval.proto = P_POP2; return PROTO; }
(sdps)|(SDPS) { return SDPS; }
(pop3)|(POP3) { yylval.proto = P_POP3; return PROTO; }
(imap-k4)|(IMAP-K4) { yylval.proto = P_IMAP_K4; return PROTO; }
(imap-gss)|(IMAP-GSS) { yylval.proto = P_IMAP_GSS; return PROTO; }
(imap)|(IMAP) { yylval.proto = P_IMAP; return PROTO; }
(apop)|(APOP) { yylval.proto = P_APOP; return PROTO; }
(etrn)|(ETRN) { yylval.proto = P_ETRN; return PROTO; }
(kpop)|(KPOP) { return KPOP; }
(#.*)?\\?\n { prc_lineno++; } /* newline is ignored */
[0-9]+ { yylval.number = atoi(yytext); return NUMBER; }
[^=;:, \t\r\n]+ {
char buf[MSGBUFSIZE];
escapes(yytext, buf);
yylval.sval = (char *) xstrdup(buf);
return STRING;
}
[ \t\r]+ ; /* whitespace */
%%
void escapes(cp, tp)
/* process standard C-style escape sequences in a string */
const char *cp; /* source string with escapes */
char *tp; /* target buffer for digested string */
{
while (*cp)
{
int cval = 0;
if (*cp == '\\' && strchr("0123456789xX", cp[1]))
{
char *dp;
const char *hex = "00112233445566778899aAbBcCdDeEfF";
int dcount = 0;
if (*++cp == 'x' || *cp == 'X')
for (++cp; (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
cval = (cval * 16) + (dp - hex) / 2;
else if (*cp == '0')
while (strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
cval = (cval * 8) + (*cp++ - '0');
else
while ((strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
cval = (cval * 10) + (*cp++ - '0');
}
else if (*cp == '\\') /* C-style character escapes */
{
switch (*++cp)
{
case '\\': cval = '\\'; break;
case 'n': cval = '\n'; break;
case 't': cval = '\t'; break;
case 'b': cval = '\b'; break;
case 'r': cval = '\r'; break;
default: cval = *cp;
}
cp++;
}
else
cval = *cp++;
*tp++ = cval;
}
*tp = '\0';
}
|
